!   TITLE:  tv_revolve_aset.mac (SM_TOOL)
!
!
!   TOOLBAR VERSION
!
!   This sub-macro revolves a selected set of areas around an axis
!   defined by 2 keypoints, AXP1 and AXP2. The total angle of revolve
!   is defined by REVANG; and the number of volume segments in the
!   revolve are specified by NUMSEG. Input necessary are:
!
!       A selected set of areas (each to be extruded)
!
!       axp1 = 1st axis point of revolution
!
!       axp2 = 2nd axis point of revolution
!
!       revang = angle of revolve
!
!       numseg = number of volume segments
!
!
!
! REVOLVE_ASET, axp1, axp2, revang, numseg
!
!
!
*get,prkey_,active,0,prkey
/nopr

*ask,axp1,Axis Point 1,
*ask,axp2,Axis Point 2,
*ask,revang,Revolve Angle,360
*ask,numseg,# Volume segments,4
!
*get,alow,area,,num,min
*get,ahigh,area,,num,max
!
*do,iiii_,alow,ahigh,1
    *if,asel(iiii_),ne,0,then
        vrotat,iiii_,,,,,,axp1,axp2,revang,numseg
    *endif
*enddo
!
init_entity_num
!
lplot
!
*set,axp1,
*set,axp2,
*set,iiii_,
*set,revang,
*set,numseg,
*set,alow,
*set,ahigh,
!
abbres,new,tools,mac

*if,prkey_,eq,1,then
    /go
*endif