!   TITLE:  radius.mac (MANAGEMENT)
!
!
!   This sub-macro creates an array of radial dimensions, where each
!   element of the array corresponds to a specific radius in the array.
!   The array can be input up to 18 elements.  These radii are the
!   distances to each point in the volume profile defined by the user as
!   input into PROFILE_BORE.MAC. This allows for the user to specify a
!   special shaped profile volume at the angular intervals defined by
!   ANG_ARRAY.MAC.
!
!   num_rad = # of radii values to create the profile. The number of these
!             radii is always 1 less than the 'num_pnt' value specified
!             in DEPTH.MAC when used for PROFILE_BORE.MAC. This is due to
!             the last point in DEPTH.MAC being along the axis of rotation,
!             and therefore has a 0 (zero) radius.
!
!   radius#n = (non-zero) radial distance of point n.
!
!
!
! RADIUS, num_rad, radius#1, radius#2, radius#3,......, radius#18
!
!
*get,prkey_,active,0,prkey
/nopr

num_rad=arg1
!
*dim,rad,array,num_rad
!
*do,ijk_,2,(num_rad+1),1
    !
    jkl_=ijk_-1
    !
    *if,ijk_,lt,10,then
        rad(jkl_,1)=arg%ijk_%
    *else
        rad(jkl_,1)=ar%ijk_%
    *endif
*enddo
!
*set,ijk_,
*set,jkl_,


*if,prkey_,eq,1,then
    /go
*endif