!   TITLE:  featr_set.mac (MANAGEMENT)
!
!
!   OBJECTIVE:
!
!   This macro selects a specified solid model entity feature(s) and all
!   associated lower solid model entities for the display.
!
!
!   COMMAND SYNTAX:
!
!                     (1)      (2)
!        FEATR_SET, ftr_typ, ftr_num
!
!
!   ARGUMENTS:
!
!       (1) ftr_typ = the solid model entity feature type:
!
!                   1 (or blank) = volume(s)
!
!                   2 = area(s)
!
!                   3 = line(s)
!
!       (2) ftr_num = the number or component group name of the feature(s).
!
!
!   DESCRIPTION:
!
!   This macro is used if it is desired to display only a particular volume,
!   area or line, and all associated lower solid model entities. The default
!   solid model entity type is volumes. Therefore, by default, a specified
!   volume, and associated areas, lines and keypoints comprising the volume,
!   is selected and displayed. The solid model entity maximum parameters is
!   unaffected, and may be used for implementing parameterized solid model
!   operations.
!
!
!
*get,prkey_,active,0,prkey
/nopr

ftrtyp_=arg1
ftrnum_=arg2
!
*if,ftrtyp_,eq,0,then
    ftrtyp_=1
*endif
!
*if,ftrnum_,ne,0,then
    *if,ftrtyp_,eq,1,then
        vsel,s,volu,,ftrnum_
        aslv,s
        lsla,s
        ksll,s
    *elseif,ftrtyp_,eq,2,then
        asel,s,area,,ftrnum_
        lsla,s
        ksll,s
    *elseif,ftrtyp_,eq,3,then
        lsel,s,line,,ftrnum_
        ksll,s
    *endif
    !
    /AUTO, 1
    /REP
    !
    lplot
*endif
!
*set,ftrtyp_,
*set,ftrnum_,

*if,prkey_,eq,1,then
    /go
*endif