!   TITLE:  ar_group.mac (MANAGEMENT)
!
!
!   OBJECTIVE:
!
!   This sub-macro selects a set of areas, from a currently selected set of
!   areas, that are attached to a line group. 
!
!
!   COMMAND SYNTAX:
!
!                   (1)   (2)   (3)
!        AR_GROUP,  skp,  dkp,  ekp
!
!
!   ARGUMENTS:
!
!       (1) skp = start keypoint (KP) in the line sequence
!
!       (2) dkp = direction keypoint. This is the next KP, in sequence, in the
!                 desired direction of travel towards the end KP (EKP).
!
!       (3) ekp = end keypoint in the line sequence
!
!
!   DESCRIPTION:
!
!   This macro may be used to select a series of areas that create a complex
!   geometric boundary, and therefore make it difficult to select by location
!   or by area number.
!
!   This macro utilizes the command macro LN_GROUP.MAC in forming the line
!   group, and then selects the areas attached. Therefore, areas attached to
!   the line group boundary as defined by the input keypoint arguments are
!   selected. 
!
!   The selected area group is stored in the component group name, 'ARGRP_'.
!
!
!
*get,prkey_,active,0,prkey
/nopr
!
skpa_=arg1
dkpa_=arg2
ekpa_=arg3
!
ln_group,skpa_,dkpa_,ekpa_,1
!
cmsel,s,lngrp_
asll,s,0
lsla,s
cm,argrp_,area
!
aplot
!
*set,skpa_,
*set,dkpa_,
*set,ekpa_,
cmdele,lngrp_
!
*if,prkey_,eq,1,then
    /go
*endif