!   TITLE:  ang_array.mac (MANAGEMENT)
!
!
!   OBJECTIVE:
!
!   This sub-macro creates an array of angular dimensions, where each
!   element of the array corresponds to a specific angle in the array.
!
!
!   COMMAND SYNTAX:
!
!                     (1)      (2)      (3)      (4) . . . . . . (19)
!        ANG_ARRAY, num_ang, angle#1, angle#2, angle#3,......, angle#18
!
!
!   ARGUMENTS:
!
!           num_ang = the number of angle dimensions.
!
!           angle#n = the nth anglular dimension.
!
!
!   DESCRIPTION:
!
!   The array can be input up to 18 elements.  These angles are the
!   volume interval distances around a circle that the user defines for
!   input into PROFILE_BORE.MAC. This allows for the user to specify a
!   special shaped profile volume at the angular intervals of this array.
!   All angles must be placed in a clockwise order for correct execution
!   in ANG_DIFF.MAC.
!
!
!
*get,prkey_,active,0,prkey
/nopr
!
num_ang=arg1
!
*dim,ang,array,num_ang
!
*do,ii_,2,(num_ang+1),1
    !
    jj_=ii_-1
    !
    *if,ii_,lt,10,then
        *if,arg%ii_%,lt,0,then
            xx_=arg%ii_%+360
            ang(jj_,1)=xx_
        *else
            ang(jj_,1)=arg%ii_%
        *endif
    *else
        *if,ar%ii_%,lt,0,then
            xx_=ar%ii_%+360
            ang(jj_,1)=xx_
        *else
            ang(jj_,1)=ar%ii_%
        *endif
    *endif
*enddo
!
*set,ii_,
*set,jj_,
*set,xx_
!
*if,prkey_,eq,1,then
    /go
*endif