/clear,start

!        M. BORRE 10/30/00
/PREP7
/TITLE, SHOCK RESPONSE OF KEARFOTT CU09696082 LVDT ARMATURE EXTENSION

ET,1,BEAM188

SECTYPE,   1, BEAM, CSOLID, armext
SECOFFSET, CENT
SECDATA,.0445,0,0,0,0,0,0,0,0,0            !.089 DIAMETER BEAM 

MP,EX,1,28E6                               !MATERIAL PROPERTIES
MP,DENS,1,73.8E-5
K,1
K,2,4.92                       ! LENGH OUTSIDE BODY = 4.92 IN 
K,3,0,1
K,4,-1.88                                  ! LENGH INSIDE BODY = 1.88 IN

!DK,1, , , ,0,UY,UZ,ROTX,ROTY,ROTZ, ,       !SLIDING CONSTRAINT
dk,1,UY,.0055,,0
DK,1, , , ,0,UZ

DK,2, , , ,0,ALL, , , , , ,                !FIXED BEAM END
!DK,4, , , ,0,UY,UZ,ROTX,ROTY,ROTZ, ,       !SLIDING CONSTRAINT

dk,4,UY,.0055,,0
DK,4, , , ,0,UZ

L,1,2
L,1,4
LATT,,,,,3,,1                              !ORIENTATION OF BEAM
ESIZE,.1                                   !MESH SIZE 
LMESH,ALL
/ESHAPE,1
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
EPLOT
FINISH
/SOLU
ANTYPE,MODAL              ! Mode-frequency analysis
MODOPT,SUBS,10            ! Subspace iteration, Extract 10 mode shapes
SOLVE
FINISH
/SOLU
ANTYPE,SPECTR             ! Spectrum analysis
SPOPT,SPRS,10,YES         ! Single point spectrum
SED,,1                    ! Global Y-axis as spectrum direction
SVTYP,2                           ! SEISMIC ACCELERATION SPECTRUM
FREQ,10,100,300,1200,4500,10000   ! FREQUENCY POINTS FOR SV VS. FREQ TABLE

! SPECTRUM VALUES ASSOCIATED WITH FREQUENCY POINTS

SV,,3*386.4,94*386.4,435*386.4,435*386.4,5340*386.4,5340*386.4


SOLVE
FINISH
/SOLU
ANTYPE,MODAL              ! Mode-frequency analysis
EXPASS,ON
MXPAND,10,,,YES,0.005     ! Expand 10 mode shapes, calculate element stresses
                          ! set signif=0.005
SOLVE
FINISH
/SOLU
ANTYPE,SPECTR
SRSS,0.15,DISP    ! Square Root of Sum of Squares Mode combination
                  ! with signif=0.15 and displacement solution requested
SOLVE
FINISH
/POST1
SET,LIST
/INP,,mcom
/EFACE,1
AVPRIN,0,0,
PLNSOL,S,EQV,0,1
FINISH