!   TITLE:  assy_ring.mac (CU09644005)
!
!-----------------------------------------------------------------------
!       Rev -   08/29/2002      D. Edwards
!       Rev A   11/04/2002      D. Edwards
!               Changed contraints to contact elements.  They work for
!               the shoulder but not for the press fit interface.
!-----------------------------------------------------------------------
!
!   Ring Assy
!
!   assy_ring,pfit,bload
!
!
!************************** TABLE OF CONTENTS **************************
!
!       Model Assembly Preparation
!
!   1.  Parameter List
!   2.  Model Coordinate System
!   3.  Solid Model
!
!********************* Model Assembly Preparation **********************
!
!<<<<<<<<<<<<<<<<<<<<<<<< 1.  Parameter List >>>>>>>>>>>>>>>>>>>>>>>>>>
!
!clear_start_new

nomsg

pin,1

ring

! pfit = arg1 = 1 to include press fit effects, otherwise bending only
pfit=arg1
Rdelta=.0005                    ! Amount of total radial interference

! bload = arg2 = 1 to apply 50# bending load (100/2 for symmetry)
bload=arg2
Flaterl=100                     ! Applied lateral load

! Define contact element types

ET,100,CONTAC52,,,0,0
MP,mu,100,0

!      1   2     3    4     5      6   7   8
!     KN, GAP, START, KS, REDFACT, NX, NY, NZ
R,100,1e8,0,,,,0
rmore,1,0                       ! shoulder real constant set
R,101,1e8,-Rdelta,,,,1          ! Press fit contact element real constant set

parm_val,'pin','y7','ztop'
parm_val,'pin','x2','rhole'
parm_val,'pin','x5','rs'        ! Radius to shoulder
parm_val,'ring','len','len'

parm_val,'pin','y11','zcen'
parm_val,'pin','r1','rsph'

csys,CSrz0
create_cs,0,'CSrz1',1

alls
nrotat,all

! Constrain nodes at shoulder
csys,CSrz1
lsel,s,loc,z,ztop
lsel,r,loc,x,rhole,rs
asll,s,1
nsla,s,1
nsel,r,loc,y,91,180     !113, 180
!cpintf,UZ
mat,100
type,100
real,100
eintf,,,low,CSrz1

! Constrain press fit diameters and axially for weld
csys,CSrz1
lsel,s,loc,x,rhole
asll,s,1
nsla,s,1
cpintf,UX       !radial direction
!mat,100
!type,100
!real,101
!eintf,,,low,CSrz1

! Simulate weld at bottom
nsel,r,loc,z,0,.025
cpintf,UZ

! Constrain ends of ring
csys,CSrz0
nsel,s,loc,x,-len/2
nsel,a,loc,x,len/2
nrotat,all
d,all,UX,,,,,UZ

! Constrain plane of symmetry
csys,CSrz0
nsel,s,loc,y,0
d,all,UY

alls

*if,bload,eq,1,then
    ! Apply load
    csys,CSrz0
    f,node(rsph,0,zcen),FX,-Flaterl/2
*endif

fini

tstart

/sol

antype,0

eqslv,pcg,1E-6,2    ! Gives same ans as wavefront in less than 1/2 the time

*if,pfit,eq,1,then
    rdelta=.0005        ! Radial interference between parts
    tfinal=rdelta/(rhole*1.0e-6)

    tunif,tfinal
    tref,0
*endif

solv

tstop