!   TITLE:  gyro_cap_cres.mac (AAAV)
!
!-----------------------------------------------------------------------
!       Rev -   RELEASED    12/13/2001      J. Rinaldi
!       Rev A               05/02/2002      D. Edwards
!               Added assy cuts for GIMBAL FRAME ASSY (MATCHED SET)
!               P/N SK400A013
!-----------------------------------------------------------------------
!
!   This part macro creates the AAAV gimbal gyro cap: SK324A011
!
!   CSgyrc0:            Cartesian Gyro Cap Coordinate System
!   CSgyrc1:            Cylindrical Gyro Cap Coordinate System
!   CSgyrc2:            Spherical Gyro Cap Coordinate System
!
!************************** TABLE OF CONTENTS **************************
!
!       Model Assembly Preparation
!
!   1.  Parameter List
!   2.  Model Coordinate System
!   3.  Solid Model
!
!********************* Model Assembly Preparation **********************
!
mod_assemb_prep,arg1,arg2,arg3
!
!<<<<<<<<<<<<<<<<<<<<<<<< 1.  Parameter List >>>>>>>>>>>>>>>>>>>>>>>>>>
!
gyro_cap_cres.parm
!
!<<<<<<<<<<<<<<<<<<<< 2.  Model Coordinate System >>>>>>>>>>>>>>>>>>>>>
!
mod_coord_system,acs,xc,yc,zc,rotxyc,rotyzc,rotzxc
!
!<<<<<<<<<<<<<<<<<<<<<<<<<<< 3.  Solid Model >>>>>>>>>>>>>>>>>>>>>>>>>>
!
!
!---------------------------- 3.1 Main Body ---------------------------
!
csys,CSgyrc1
!
create_arcs,rcapi,,,1,0,Da01/2
!
create_arcs,rcapo,,,1,0,(Da01/2)-1
!
csys,CSgyrc0
!
k,,Dx01,(rcapo+rcapi)/2,0
k,,Dx01,Dy01/2,0
!
k,,Dx01,Dy01/2,0
k,,0,Dy01/2,0
!
k,,0,Dy01/2,0
k,,0,rcapi,0
!
k,,rcapo,0,0
k,,rcapi,0,0
!
ln_series
!
profile_close
!
ln_fillet,km,rfilcap
!
create_area-lines
!
hole_pattern,CSgyrc1,Dpat/2,0,3,,360-45,90,D01
!
csys,CSgyrc0
arsym,y,all,,,,1,0
!
init_entity_num
!
aadd,all
!
init_entity_num
!
adele,am
!
init_entity_num
!
ksel,s,kp,,km-5,km,1
ln_fillet,,rfilcap
!
create_vol-lines,Dz01
!
lplot
!
!-------------------------- 3.2  Screw Holes --------------------------
!
*if,f_mesh_,ne,1,then
    csys,CSgyrc0
    create_cs,0,'CSgscr10',0,rcapo,Dy02,-Dz01/2,0,0,90
    !
    create_circle,Dd01/2
    create_area-lines
    !
    csys,CSgyrc0
    create_cs,0,'CSgscr20',0,rcapo,-Dy02,-Dz01/2,0,0,90
    !
    create_circle,Dd01/2
    create_area-lines
    !
    cm,vset1,volu
    isolate_areas
    extrude_aset,-rcapo
    !
    vsel,s,volu,,vm-1,vm,1
    cm,vset2,volu
    !
    init_entity_num
    !
    vsbv,vset1,vset2,,delete,delete
    !
    init_entity_num
    !
    csys,CSgscr10
    create_circle,Dd02/2
    create_area-lines
    !
    csys,CSgscr20
    create_circle,Dd02/2
    create_area-lines
    !
    cm,vset1,volu
    isolate_areas
    extrude_aset,-(rcapo-Dz02)
    !
    vsel,s,volu,,vm-1,vm,1
    cm,vset2,volu
    !
    init_entity_num
    !
    vsbv,vset1,vset2,,delete,delete
    !
    init_entity_num
    !
    lplot
*endif
!

!
! HOLE_PATTERN, csnum, rpat, zpos, numh, anginc, stang, patang, dhole
!
!hole_pattern,CSgyrc1,Dpat/2,0,3,,360-45,90,.138

*if,assemble,eq,1,then

    ! Add assembly cuts (Rev A)
    !
    csys,CSgyro0                ! Face cut
    !
    create_circle,gR01M
    !
    create_vol-lines,-(gL15-gL11-gDx02M)
    !
    vsbv,vm-1,vm,,delete,delete
    !
    init_entity_num
    !
    csys,CSgyro0                ! Thru Bore
    !
    create_circle,gD02M/2
    !
    create_vol-lines,-1.00
    !
    vsbv,vm-1,vm,,delete,delete
    !
    init_entity_num
    !
    lplot
    !

*endif

! Assembly machine cut
csys,CSgyrc1

cm,vset1,volu

create_circle,Dr01
create_vol-lines,-1

vsbv,vset1,vm,,delete,delete

init_entity_num

lplot

*if,f_solve,eq,1,then

    !
    asel,selv,loc,z,0
    !
    msh_standrd,3,,,5,1,2,0.080,0.080
    !
    csys,CSgyrc1
    nsel,s,loc,y,90,270
    dsym,symm,y,CSgbc1
    !
    csys,CSgyrc0
    nsel,s,loc,x,0
    nsel,r,loc,y,Dr01
    nsel,r,loc,z,0
    !
    d,all,all
    !
    csys,CSgyrc0
    nsel,s,loc,x,0
    nsel,r,loc,y,Dr01
    nsel,r,loc,z,-Dz01
    !
    d,all,ux
    !
    init_entity_num
    !
    radial_asel,'s',CSgbc1,Dr01,Dr01,270,90+360,0,-Dz01
    sfa,all,,pres,10
    !
    init_entity_num
    !
    eplot
    !
    /solu
    eqslv,iter,5,3
    solve
    !
    FINISH
    /POST1
    /EFACE,1
    AVPRIN,0,0,
    /title,Gimbal Bearing Cap / CRES 410 / SK324A010 / Radial Delection
    !
    rsys,CSgbc1
    PLNSOL,U,X,2,1
    !
    create_image
    !
    /EFACE,1
    AVPRIN,0,0,
    /title,Gimbal Bearing Cap / CRES 410 / SK324A010 / Stress
    !
    PLNSOL,S,EQV,0,1
    !
    create_image
*else
    finalize_model
*endif