!   TITLE:  gimb_brg_cp_cres.mac (AAAV)
!
!-----------------------------------------------------------------------
!       Rev -   09/01/2001      J. Rinaldi
!-----------------------------------------------------------------------
!
!   This part macro creates the AAAV gimbal bearing cap: SK324A010
!
!   CSgbc0:     Cartesian Gimbal Bearing Cap Coordinate System
!   CSgbc1:     Cylindrical Gimbal Bearing Cap Coordinate System
!   CSgbc2:     Spherical Gimbal Bearing Cap Coordinate System
!
!
!************************** TABLE OF CONTENTS **************************
!
!       Model Assembly Preparation
!
!   1.  Parameter List
!   2.  Model Coordinate System
!   3.  Solid Model
!       3.1  Main Body
!       3.2  Screw Holes
!       3.3  Web Contour Cuts
!
!********************* Model Assembly Preparation **********************
!
mod_assemb_prep,arg1,arg2,arg3
!
!<<<<<<<<<<<<<<<<<<<<<<<< 1.  Parameter List >>>>>>>>>>>>>>>>>>>>>>>>>>
!
gimb_brg_cp_cres.parm
!
!<<<<<<<<<<<<<<<<<<<< 2.  Model Coordinate System >>>>>>>>>>>>>>>>>>>>>
!
mod_coord_system,acs,xc,yc,zc,rotxyc,rotyzc,rotzxc
!
!<<<<<<<<<<<<<<<<<<<<<<<<<<< 3.  Solid Model >>>>>>>>>>>>>>>>>>>>>>>>>>
!
!
!---------------------------- 3.1  Main Body --------------------------
!
csys,CSgbc1
!
create_arcs,rcapi,,,1,0,Da01/2
!
create_arcs,rcapo,,,1,0,(Da01/2)-1
!
csys,CSgbc0
!
k,,Dx01,(rcapo+rcapi)/2,0
k,,Dx01,Dy01/2,0
!
k,,Dx01,Dy01/2,0
k,,0,Dy01/2,0
!
k,,0,Dy01/2,0
k,,0,rcapi,0
!
k,,rcapo,0,0
k,,rcapi,0,0
!
ln_series
!
profile_close
!
ln_fillet,km,rfilcap
!
create_vol-lines,Dz01
!
lplot
!
!-------------------------- 3.2  Screw Holes --------------------------
!
*if,f_mesh_,ne,1,then
    csys,CSgbc0
    create_cs,0,'CSscrw10',0,rcapo,Dy04,-(Dz01-Dz04),0,0,90
    !
    create_circle,Dd02/2
    create_area-lines
    !
    csys,CSgbc0
    create_cs,0,'CSscrw20',0,rcapo,Dy04,-(Dz01-Dz04-Dz05),0,0,90
    !
    create_circle,Dd02/2
    create_area-lines
    !
    cm,vset1,volu
    isolate_areas
    extrude_aset,-rcapo
    !
    vsel,s,volu,,vm-1,vm,1
    cm,vset2,volu
    !
    init_entity_num
    !
    vsbv,vset1,vset2,,delete,delete
    !
    init_entity_num
    !
    csys,CSscrw10
    create_circle,Dd03/2
    create_area-lines
    !
    csys,CSscrw20
    create_circle,Dd03/2
    create_area-lines
    !
    cm,vset1,volu
    isolate_areas
    extrude_aset,-(rcapo-Dz06)
    !
    vsel,s,volu,,vm-1,vm,1
    cm,vset2,volu
    !
    init_entity_num
    !
    vsbv,vset1,vset2,,delete,delete
    !
    init_entity_num
    !
    lplot
*endif
!
!----------------------- 3.3  Web Contour Cuts ------------------------
!
csys,CSgbc1
!
*if,dt,eq,0,then
    dt=(Dz01-(n+1)*w)/n                 ! tool diameter calculation
*else
    w=(Dz01-dt*n)/(n+1)
*endif
!
*if,phi,eq,0,then
    phi=(((b+dt)/2)/rcapo)*dconv
    theta=90-(acos((Dy04-(Dd03/2))/rcapo)*dconv)
*endif
!
phihld=phi
thetahld=theta
!
*do,i,1,n,1
    *if,i,eq,1,then
        phi=12
        theta=48
    *else
        phi=phihld
        theta=thetahld
    *endif
    !
    vsel,s,volu,,vm
    x=-(i*w+(((2*i)-1)/2)*dt)
    mach_op,'t','b',dt,,rcapo-Dr01-dcut,CSgbc1,rcapo,phi,theta,x
*enddo
!
csys,CSgbc0
vsymm,y,all,,,,1,0
vadd,all
init_entity_num
!
hole_pattern,CSgbc1,2.860/2,0,3,,300,120,0.138
isolate_areas
extrude_aset,-0.450
vsel,s,volu,,vm-2,vm,1
cm,vset1,volu
init_entity_num
vsbv,vm-3,vset1,,delete,delete
init_entity_num
aplot


*go,:skip


ang_cut_pln,phi
ang_cut_pln,theta
!
csys,CSgbc0
init_entity_num
!
vsymm,y,all,,,,1,0
init_entity_num
!
csys,CSgbc1
vsel,selv,loc,y,-phi,phi
vsel,r,loc,z,-Dz01,0
vadd,all
init_entity_num
!
lplot

:skip

csys,CSgbc1

create_circle,Dr01
create_vol-lines,-3

vsbv,vm-1,vm,,delete,delete

init_entity_num

lplot

*if,f_solve,eq,1,then
    !
    msh_standrd,4,,,,,3,0.1,0.1
    !
    csys,CSgbc1
    nsel,s,loc,y,90,270
    dsym,symm,y,CSgbc1
    !
    csys,CSgbc0
    nsel,s,loc,x,0
    nsel,r,loc,y,Dr01
    nsel,r,loc,z,0
    !
    d,all,all
    !
    csys,CSgbc0
    nsel,s,loc,x,0
    nsel,r,loc,y,Dr01
    nsel,r,loc,z,-Dz01
    !
    d,all,ux
    !
    init_entity_num
    !
    radial_asel,'s',CSgbc1,Dr01,Dr01,270,90+360,0,-Dz01
    sfa,all,,pres,10
    !
    init_entity_num
    !
    eplot
    !
    /solu
    eqslv,iter,5,3
    solve
    !
    FINISH
    /POST1
    /EFACE,1
    AVPRIN,0,0,
    /title,Gimbal Bearing Cap / CRES 410 / SK324A010 / Radial Delection
    !
    rsys,CSgbc1
    PLNSOL,U,X,2,1
    !
    create_image
    !
    /EFACE,1
    AVPRIN,0,0,
    /title,Gimbal Bearing Cap / CRES 410 / SK324A010 / Stress
    !
    PLNSOL,S,EQV,0,1
    !
    create_image

*else
    finalize_model
*endif