!   TITLE:  plate_brg_id.mac (AAAV)
!
!-----------------------------------------------------------------------
!       Rev -   01/17/2003      D. Edwards
!-----------------------------------------------------------------------
!
!   Analysis of upper azimuth bearing retainer to determine clamping
!   load on inner DT bearing races.
!
!   SUPPORT, BEARING    P/N 333A056
!
!   (Little Boys) CU01715076/104 steel sleeve version with A311A105-101
!    DT bearings (3.875 OD).
!
!   CS_0:       Cartesian ring Coordinate System
!   CS_1:       Cylindrical ring Coordinate System
!   CS_2:       Spherical ring Coordinate System
!
!************************** TABLE OF CONTENTS **************************
!
!       Model Assembly Preparation
!
!   1.  Parameter List
!   2.  Model Coordinate System
!   3.  Solid Model
!
!********************* Model Assembly Preparation **********************
!
mod_assemb_prep,arg1,arg2,arg3      ! prepare database for assembly
!
!<<<<<<<<<<<<<<<<<<<<<<<< 1.  Parameter List >>>>>>>>>>>>>>>>>>>>>>>>>>
!
plate_brg_id.parm
!
!<<<<<<<<<<<<<<<<<<<< 2.  Model Coordinate System >>>>>>>>>>>>>>>>>>>>>
!
mod_coord_system,acs,xc,yc,zc,rotxyc,rotyzc,rotzxc
!
!<<<<<<<<<<<<<<<<<<<<<<<<<<< 3.  Solid Model >>>>>>>>>>>>>>>>>>>>>>>>>>
!
csys,CS_0

k,,r1           ! 1
k,,r2           ! 2
k,,r2,t2        ! 3
k,,rb,t2        ! 4
k,,r3,t2        ! 5
k,,r3,t1        ! 6
k,,ro,t1        ! 7
k,,ri,t1        ! 8
k,,r1,t1        ! 9

create_area

view,'f'

! Apply pressure load along annulus about bolt pattern
lsel,s,loc,x,ri,ro
lsel,r,loc,y,t1
sfl,all,pres,Pt
alls

!MSH_AREA, mstyp, mshdens, etpa, elmnl, elmxl, lszmsh, mat, real, ecs
msh_area,0,0,1,.01,.01,,c416

! Apply contact elements at bearing race contact
lsel,s,loc,x,rb,r3
lsel,r,loc,y,t2
nsll,s,1                    ! 0=interior nodes only
ngen,2,nm+1,all,,,,-.01     ! Copy nodes down y=-.01

type,2
mat,2
real,2

eintf,,,low,0,0,-.01,0

nsll,u,1
d,all,uy
d,all,ux

init_entity_num

! Apply contact elements at stub shaft contact
lsel,s,loc,x,r1,r2
lsel,r,loc,y,0
nsll,s,1
ngen,2,nm+1,all,,,,-.01     ! Copy nodes down y=-.01

type,2
mat,2
real,3

eintf,,,low,0,0,-.01,0

nsll,u,1
d,all,uy
d,all,ux

init_entity_num,1

fini

/sol

antype,0

solcontrol
!autots,on
!nsub,20
solv

fini

/post1

/dscale,,1

avprin,0,0,
plnsol,s,eqv,2,1

/nopr
alls
fsum,0,all
*get,Ftplate,fsum,0,ITEM,FY

nsel,s,loc,x,rb,r3
fsum,0,all
*get,Ft,fsum,0,ITEM,FY
/gopr

*msg,ui,Ftplate,Ft
_Total load on entire plate:______ %5I %/&
Total load applied to inner race:_ %5I


/eof

lsel,s,line,,1
nsll,s,1
fcn1='GAP+'
rplot_nodal,0,'x','U','Y'